Красивые часы на Arduino + TFT IPS + DS3231

#include <TFT_eSPI.h>
#include <RTClib.h>

TFT_eSPI tft;
RTC_DS3231 rtc;

const int btnMode = 7;
const int btnUp   = 6;

byte mode = 0; // 0-часы, 1-минуты, 2-день, 3-месяц, 4-год

int daysInMonth(int month, int year) {
  if (month == 2) {
    return (year % 4 == 0 && (year % 100 != 0 || year % 400 == 0)) ? 29 : 28;
  }
  if (month == 4 || month == 6 || month == 9 || month == 11) return 30;
  return 31;
}

void setup() {
  pinMode(btnMode, INPUT_PULLUP);
  pinMode(btnUp,   INPUT_PULLUP);

  tft.begin();
  tft.setRotation(1);
  tft.fillScreen(TFT_BLACK);
  tft.setTextColor(TFT_WHITE);

  rtc.begin();
}

void loop() {
  DateTime now = rtc.now();

  tft.fillScreen(TFT_BLACK);
  tft.setTextSize(2);
  tft.setCursor(10, 10);
  tft.println("Мои часы");

  tft.setTextSize(3);
  tft.setCursor(40, 60);
  tft.printf("%02d:%02d:%02d", now.hour(), now.minute(), now.second());

  const char* days[7] = {"Вс","Пн","Вт","Ср","Чт","Пт","Сб"};
  tft.setTextSize(2);
  tft.setCursor(20, 110);
  tft.print(days[now.dayOfTheWeek()]);
  tft.print(" ");
  tft.printf("%02d.%02d.%04d", now.day(), now.month(), now.year());

  tft.setCursor(70, 160);
  tft.print(rtc.getTemperature(), 1);
  tft.print(" C");

  if (digitalRead(btnMode) == LOW) {
    delay(200);
    mode = (mode + 1) % 5;
  }

  if (digitalRead(btnUp) == LOW) {
    delay(200);
    DateTime nt = now;

    switch (mode) {
      case 0:
        nt = DateTime(now.year(), now.month(), now.day(), (now.hour() + 1) % 24, now.minute(), 0);
        break;
      case 1:
        nt = DateTime(now.year(), now.month(), now.day(), now.hour(), (now.minute() + 1) % 60, 0);
        break;
      case 2: {
        int maxDay = daysInMonth(now.month(), now.year());
        int d = now.day() + 1;
        if (d > maxDay) d = 1;
        nt = DateTime(now.year(), now.month(), d, now.hour(), now.minute(), 0);
        break;
      }
      case 3: {
        int m = now.month() + 1;
        if (m > 12) m = 1;
        int d = min(now.day(), daysInMonth(m, now.year()));
        nt = DateTime(now.year(), m, d, now.hour(), now.minute(), 0);
        break;
      }
      case 4:
        nt = DateTime(now.year() + 1, now.month(), now.day(), now.hour(), now.minute(), 0);
        break;
    }
    rtc.adjust(nt);
  }

  delay(100);
}